[Python-checkins] cpython (merge 3.5 -> default): Merge from 3.5
steve.dower
python-checkins at python.org
Mon Jun 27 12:43:40 EDT 2016
https://hg.python.org/cpython/rev/aa1e1f7e17cc
changeset: 102214:aa1e1f7e17cc
parent: 102212:a14f425e1c4a
parent: 102213:2210765a2770
user: Steve Dower <steve.dower at microsoft.com>
date: Mon Jun 27 09:43:27 2016 -0700
summary:
Merge from 3.5
files:
Tools/nuget/build.bat | 55 +++++++++++++++++++++++++++++++
1 files changed, 55 insertions(+), 0 deletions(-)
diff --git a/Tools/nuget/build.bat b/Tools/nuget/build.bat
new file mode 100644
--- /dev/null
+++ b/Tools/nuget/build.bat
@@ -0,0 +1,55 @@
+ at echo off
+setlocal
+set D=%~dp0
+set PCBUILD=%D%..\..\PCBuild\
+
+set BUILDX86=
+set BUILDX64=
+set REBUILD=
+set OUTPUT=
+set PACKAGES=
+
+:CheckOpts
+if "%~1" EQU "-h" goto Help
+if "%~1" EQU "-x86" (set BUILDX86=1) && shift && goto CheckOpts
+if "%~1" EQU "-x64" (set BUILDX64=1) && shift && goto CheckOpts
+if "%~1" EQU "-r" (set REBUILD=-r) && shift && goto CheckOpts
+if "%~1" EQU "-o" (set OUTPUT="/p:OutputPath=%~2") && shift && shift && goto CheckOpts
+if "%~1" EQU "--out" (set OUTPUT="/p:OutputPath=%~2") && shift && shift && goto CheckOpts
+if "%~1" EQU "-p" (set PACKAGES=%PACKAGES% %~2) && shift && shift && goto CheckOpts
+
+if not defined BUILDX86 if not defined BUILDX64 (set BUILDX86=1) && (set BUILDX64=1)
+
+call "%D%..\msi\get_externals.bat"
+call "%PCBUILD%env.bat" x86
+
+if defined PACKAGES set PACKAGES="/p:Packages=%PACKAGES%"
+
+if defined BUILDX86 (
+ if defined REBUILD ( call "%PCBUILD%build.bat" -e -r
+ ) else if not exist "%PCBUILD%win32\python.exe" call "%PCBUILD%build.bat" -e
+ if errorlevel 1 goto :eof
+
+ msbuild "%D%make_pkg.proj" /p:Configuration=Release /p:Platform=x86 %OUTPUT% %PACKAGES%
+ if errorlevel 1 goto :eof
+)
+
+if defined BUILDX64 (
+ if defined REBUILD ( call "%PCBUILD%build.bat" -p x64 -e -r
+ ) else if not exist "%PCBUILD%amd64\python.exe" call "%PCBUILD%build.bat" -p x64 -e
+ if errorlevel 1 goto :eof
+
+ msbuild "%D%make_pkg.proj" /p:Configuration=Release /p:Platform=x64 %OUTPUT% %PACKAGES%
+ if errorlevel 1 goto :eof
+)
+
+exit /B 0
+
+:Help
+echo build.bat [-x86] [-x64] [--out DIR] [-r] [-h]
+echo.
+echo -x86 Build x86 installers
+echo -x64 Build x64 installers
+echo -r Rebuild rather than incremental build
+echo --out [DIR] Override output directory
+echo -h Show usage
--
Repository URL: https://hg.python.org/cpython
More information about the Python-checkins
mailing list